gradle-play-publisher/settings.gradle.kts at master · Triple-T/gradle-play-publisher · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
import org.gradle.kotlin.dsl.version

pluginManagement {
    repositories {
        gradlePluginPortal()
        google()
    }
}

plugins {
    id("com.gradle.develocity") version "4.3.1"
}

include(
    ":common:utils", ":common:validation",

    ":play:plugin", ":play:android-publisher"
)

// sets name explicitly to make sure it uses the in intended `artifactId` in the plugin POM
project(":play:plugin").name = "play-publisher"

dependencyResolutionManagement {
    repositories {
        google().content {
            includeGroup("com.android")
            includeGroupByRegex("com\\.android\\..*")
            includeGroupByRegex("com\\.google\\..*")
            includeGroupByRegex("androidx\\..*")
        }

        mavenCentral()
    }

    versionCatalogs {
        create("libs") {
            version("depUpdates", "0.50.0")
            version("gradlePublish", "1.2.1")
            version("nexusPublish", "2.0.0")
            version("lint-gradle", "1.0.0")

            plugin("depUpdates", "com.github.ben-manes.versions")
                .versionRef("depUpdates")
            plugin("gradlePublish", "com.gradle.plugin-publish")
                .versionRef("gradlePublish")
            plugin("nexusPublish", "io.github.gradle-nexus.publish-plugin")
                .versionRef("nexusPublish")
            plugin("lint", "com.android.lint").versionRef("agp")

            version("agp", "9.0.0")
            version("agp-tools", "32.0.0")
            version("android-publisher", "v3-rev20260706-2.0.0")
            version("api-client", "2.2.0")
            version("http-client", "1.43.3")
            version("http-auth", "1.20.0")
            version("guava", "32.1.3-jre")

            library("agp", "com.android.tools.build", "gradle").versionRef("agp")
            library("agp-test", "com.android.tools.build", "builder-test-api").versionRef("agp")
            library("agp-common", "com.android.tools", "common").versionRef("agp-tools")
            library("agp-ddms", "com.android.tools.ddms", "ddmlib").versionRef("agp-tools")
            library("androidpublisher", "com.google.apis", "google-api-services-androidpublisher")
                .versionRef("android-publisher")
            library("client-api", "com.google.api-client", "google-api-client")
                .versionRef("api-client")
            library("client-http", "com.google.http-client", "google-http-client-apache-v2")
                .versionRef("http-client")
            library("client-auth", "com.google.auth", "google-auth-library-oauth2-http")
                .versionRef("http-auth")
            library("client-gson", "com.google.http-client", "google-http-client-gson")
                .versionRef("http-client")
            library("guava", "com.google.guava", "guava").versionRef("guava")
            library("lint-gradle", "androidx.lint", "lint-gradle").versionRef("lint-gradle")
        }

        create("testLibs") {
            version("junit", "5.14.2")
            version("junit-launcher", "1.14.2")
            version("truth", "1.1.5")
            version("mockito", "5.8.0")

            library("junit", "org.junit.jupiter", "junit-jupiter-api").versionRef("junit")
            library("junit-launcher", "org.junit.platform", "junit-platform-launcher")
                .versionRef("junit-launcher")
            library("junit-engine", "org.junit.jupiter", "junit-jupiter-engine")
                .versionRef("junit")
            library("junit-params", "org.junit.jupiter", "junit-jupiter-params")
                .versionRef("junit")
            library("truth", "com.google.truth", "truth").versionRef("truth")
            library("mockito", "org.mockito", "mockito-core").versionRef("mockito")
        }
    }
}